Temperature and humidity alarm

/*
  05 — Temperature and humidity alarm
  Board: ESP32.  Parts: DHT11, buzzer module, LCD 1602 (I2C backpack).
  Libraries: "DHT sensor library" (Adafruit) + Adafruit Unified Sensor,
             "LiquidCrystal I2C" (Frank de Brabander).

  Wiring:
    DHT11:  VCC -> 3V3, GND -> GND, DATA -> GPIO 4
    Buzzer: VCC -> 3V3 (or VIN), GND -> GND, IO -> GPIO 23   (active buzzer: HIGH = sound)
    LCD:    VCC -> VIN (5 V), GND -> GND, SDA -> GPIO 21, SCL -> GPIO 22

  The alarm switches ON above ALARM_ON and OFF only below ALARM_OFF. That gap
  (hysteresis) is what stops it chattering when the reading wobbles by 0.1 C —
  the same trick a real thermostat uses.
*/

#include "DHT.h"
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

const int DHT_PIN    = 4;
const int BUZZER_PIN = 23;

const float ALARM_ON  = 30.0;   // C — set for your room
const float ALARM_OFF = 28.5;   // must be lower than ALARM_ON

DHT dht(DHT_PIN, DHT11);
LiquidCrystal_I2C lcd(0x27, 16, 2);
bool alarm = false;

void setup() {
  Serial.begin(115200);
  pinMode(BUZZER_PIN, OUTPUT);
  digitalWrite(BUZZER_PIN, LOW);
  dht.begin();
  lcd.init();
  lcd.backlight();
  lcd.print("Warming up...");
}

void loop() {
  delay(2000);
  float t = dht.readTemperature();
  float h = dht.readHumidity();
  if (isnan(t) || isnan(h)) {
    lcd.setCursor(0, 1); lcd.print("sensor error    ");
    return;
  }

  if (!alarm && t >= ALARM_ON)  alarm = true;
  if ( alarm && t <= ALARM_OFF) alarm = false;
  digitalWrite(BUZZER_PIN, alarm ? HIGH : LOW);

  lcd.setCursor(0, 0);
  lcd.print("T:"); lcd.print(t, 1); lcd.print("C  H:"); lcd.print(h, 0); lcd.print("%  ");
  lcd.setCursor(0, 1);
  lcd.print(alarm ? "ALARM  >" : "ok     >");
  lcd.print(ALARM_ON, 1); lcd.print("C      ");

  Serial.print(t); Serial.print(" C  "); Serial.print(h); Serial.print(" %  ");
  Serial.println(alarm ? "ALARM" : "ok");
}